Δουλεύοντας με ένα πίνακα

Οι πίνακες διασταύρωσης (ή διπλής εισόδου, όπως αλλιώς είναι γνωστοί) είναι η πιο δημοφιλής μέθοδος, στους χρήστες του excel, για την παρουσίαση και την οργάνωση των στοιχείων τους. Οι πληροφορίες που παρέχει ένας πίνακας με λίγα στοιχεία είναι άμεσα ανιχνεύσιμες, αλλά για ένα μεγάλο πίνακα ίσως χρειαστείτε λίγη βοήθεια. Στο σημερινό σημείωμα δίνω μερικές συναρτήσεις και μορφοποιήσεις υπό όρους που ίσως διευκολύνουν την δουλειά σας με μεγάλους πίνακες. Τα παραδείγματα των εικόνων βέβαια αναφέρονται σε μικρούς πίνακες για λόγους απλότητας.
Αναζήτηση διασταύρωσης. Συναρτήσεις και υπερσύνδεση

Αναζήτηση διασταύρωσης

Ο παρακάτω τύπος με την βοήθεια της index επιστρέφει την τιμή στην διασταύρωση της γραμμής Δεκ-11 και της στήλης ΧΑΝΙΑ:
=INDEX(D9:J24;MATCH(DATEVALUE("1/12/2011");D9:D24;0);MATCH("ΧΑΝΙΑ";D9:J9;0))
Το όρισμα D9:J24 είναι ολόκληρη η περιοχή του πίνακα.
Το όρισμα MATCH(DATEVALUE(«1/12/2011»);D9:D24;0) δίνει τη θέση (13η) της τιμής Δεκ-11 μέσα στη πρώτη στήλη του πίνακα (D9:D24).
Το όρισμα αυτό μπορεί να συνταχθεί και με την συνάρτηση date αντί της datevalue
MATCH(DATE(2011;12;1);D9:D24;0)
Το όρισμα MATCH(«ΧΑΝΙΑ»;D9:J9;0) δίνει τη θέση (6η) της τιμής ΧΑΝΙΑ μέσα στην πρώτη γραμμή του πίνακα (D9:J9)
Έτσι τελικά η index κάνει τον υπολογισμό =INDEX(D9:J24;13;6) και σωστά επιστρέφει την τιμή 119.

Φυσικά τις τιμές Δεκ-11 και ΧΑΝΙΑ μπορείτε να τις δίνετε και από κελιά. Γράψτε στο κελί Α1: 1/12/2011 και στο κελί Α2: ΧΑΝΙΑ, και ο τύπος της διασταύρωσης γίνεται:
=INDEX(D9:J24;MATCH(A1;D9:D24;0);MATCH(A2;D9:J9;0))
Αντί για τη index μπορείτε να χρησιμοποιήσετε την offset, με παρόμοια σύνταξη:
=OFFSET(D9;MATCH(A1;D9:D24;0)-1;MATCH(A2;D9:J9;0)-1)
Αν ο πίνακας αλλάζει διαστάσεις, γιατί του προσθέτετε νέες γραμμές ή (και) στήλες, για να μην ξαναγράφετε κάθε φορά τον τύπο σας, ορίστε τα ορίσματά του δυναμικά με τη βοήθεια καθορισμένων ονομάτων και της offset. Μπορείτε, παράδειγμα, να καθορίσετε τα ονόματα:
πινακας =OFFSET(Φύλλο1!$D$9;0;0;COUNTA(Φύλλο1!$D$9:$D$2000);COUNTA(Φύλλο1!$D$9:$DW$9))
πρωτηγραμμη =OFFSET(Φύλλο1!$D$9;0;0;1;COUNTA(Φύλλο1!$D$9:$DW$9))
πρωτηστηλη =OFFSET(Φύλλο1!$D$9;0;0;COUNTA(Φύλλο1!$D$9:$D$2000);1)
και οι δύο παραπάνω συναρτήσεις θα γίνουν:
=INDEX(πινακας;MATCH(A1;πρωτηστηλη;0);MATCH(A2;πρωτηγραμμη;0))

=OFFSET(D9;MATCH(A1;πρωτηστηλη;0)-1;MATCH(A2;πρωτηγραμμη;0)-1)
Η γραμμή Δεκ-11 και η στήλη ΧΑΝΙΑ, διασταυρώνονται στο κελί I21. Δηλαδή στο κελί που βρίσκεται στην 21η γραμμή και στην 9η στήλη. Αν γνωρίζετε αυτούς τους 2 αριθμούς μπορείτε να βρείτε την τιμή διασταύρωσης και με την indirect. Η παρακάτω συνάρτηση θα επιστρέψει σωστά 119
=INDIRECT("R21C9";FALSE)
Ακόμα, με την hyperlink μπορείτε να δημιουργήσετε υπερσύνδεση προς την εγγραφή αυτή:
 
=HYPERLINK("##"&ADDRESS(21;9);"πάμε")
Τον αριθμό γραμμής και στήλης του κελιού μπορείτε να βρείτε  αντίστοιχα με τους τύπους:
=MATCH(A1;πρωτηστηλη;0)+ROW(D9)-1
=MATCH(A2;πρωτηγραμμη;0)+COLUMN(D9)-1
Έτσι ο τύπος indirect και ο τύπος hyperlink παίρνουν την τελική μορφή:
=INDIRECT("R"&(MATCH(A1;πρωτηστηλη;0)+ROW(D9)-1)&"C"&(MATCH(A2;πρωτηγραμμη;0)+COLUMN(D9)-1);FALSE)

=HYPERLINK("##"&ADDRESS(MATCH(A1;πρωτηστηλη;0)+ROW(D9)-1;MATCH(A2;πρωτηγραμμη;0)+COLUMN(D9)-1);"πάμε")
(Θυμίζω ότι στα κελιά Α1 και Α2 υπάρχουν οι τιμές της γραμμής και της στήλης για την οποία αναζητούμε τη διασταύρωση, στο παράδειγμά μας 1/12/2011 και ΧΑΝΙΑ αντίστοιχα).
Μορφοποίηση υπό όρους

Μορφοποίηση της στήλης και της γραμμής που επιλέξατε στα κελιά Α1 και Α2 και του κελιού διασταύρωσης

Μπορείτε ακόμα, να επιλέξετε τον πίνακα και να εισάγετε την παρακάτω μορφοποίηση υπό όρους με τύπο:
 =ADDRESS(MATCH($A$1;πρωτηστηλη;0)+ROW($D$9)-1;MATCH($A$2;πρωτηγραμμη;0)+COLUMN($D$9)-1)=CELL("address";D9)
Μόλις επιλέξετε μήνα και πόλη στα κελιά Α1 και Α2, θα μορφοποιηθεί το κελί της διασταύρωσης στο χρώμα ή τη μορφή που θέλετε. (στην εικόνα γίνεται κόκκινο).
Επίσης, αν θέλετε, μπορείτε να έχετε μορφοποίηση όλης της γραμμής ή και της στήλης που έχετε επιλέξει στα κελιά Α1 και Α2
Για την γραμμή και για τη στήλη οι τύποι της μορφοποίησης είναι αντίστοιχα:
 =MATCH($A$1;πρωτηστηλη;0)+ROW($D$9)-1=CELL("row";D9)
 =MATCH($A$2;πρωτηγραμμη;0)+COLUMN($D$9)-1=CELL("col";D9)
Για να εφαρμόσετε τις μορφοποιήσεις υπό όρους επιλέξτε πρώτα όλο τον πίνακα με το ποντίκι, ξεκινώντας από το κελί D9. Αν αργότερα προσθέσετε νέες γραμμές ή στήλες στον πίνακα, εφαρμόστε και σε αυτές τις ίδιες ρυθμίσεις με το πινέλο μορφοποίησης
Αν ο πίνακάς σας είναι στατικός και δεν έχετε ανάγκη τα καθορισμένα ονόματα, σε όλους τους παραπάνω τύπους αντικαταστήστε όπου πρωτηστηλη: D9:D24 και όπου πρωτηγραμμη: D9:J9

Για excel 2003 και προηγούμενα: Μενού: Μορφή > Μορφοποίηση υπό όρους…

Για excel 2007 & 2010: Καρτέλα Κεντρική > Μορφοποίηση υπό όρους > Δημιουργία κανόνα… Ανοίγει η καρτέλα: “Δημιουργία κανόνα μορφοποίησης”

Αντίστροφη αναζήτηση
Αντίστροφα, θέλετε να βρείτε αν μια τιμή βρίσκεται μέσα στον πίνακα και μάλιστα στη διασταύρωση ποιας γραμμής και στήλης. Για την τιμή 119 οι δύο παρακάτω συναρτήσεις:
 =INDIRECT(ADDRESS(ROW(πινακας);MAX((πινακας=119)*COLUMN(πινακας))))
 =INDIRECT(ADDRESS(MAX((πινακας=119)*ROW(πινακας));COLUMN(πινακας)))
θα επιστρέψουν αντίστοιχα: ΧΑΝΙΑ και Δεκ-11. Δηλαδή η τιμή 119 υπάρχει στον πίνακα στη διασταύρωση της γραμμής Δεκ-11 και της στήλης ΧΑΝΙΑ. Φυσικά οι συναρτήσεις καλύτερα να δέχονται τις τιμές από ένα κελί πχ Η2
 =INDIRECT(ADDRESS(ROW(πινακας);MAX((πινακας=H2)*COLUMN(πινακας))))
 =INDIRECT(ADDRESS(MAX((πινακας=H2)*ROW(πινακας));COLUMN(πινακας)))
Προσέξτε όμως, είναι συναρτήσεις-πίνακες και για να δουλέψουν πρέπει να εισαχθούν κατάλληλα. Για να εισάγετε μία “συνάρτηση – πίνακα ενός κελιού”, γράψτε τη συνάρτηση στο κελί, πατήστε στο πληκτρολόγιο F2 και μετά πατήστε Ctrl+Shift+Enter. Μόλις εισάγετε την συνάρτηση με Ctrl+Shift+Enter, το excel περικλείει τη συνάρτηση σε άγκιστρα { }. Δέστε πιο αναλυτικά στο σχετικό θέμα του ιστολογίου.
Αν η τιμή δεν υπάρχει στον πίνακα οι συναρτήσεις θα επιστρέψουν το σφάλμα #ΤΙΜΗ! Αν στον πίνακα υπάρχουν περισσότερες από μία εμφανίσεις της τιμής, οι συναρτήσεις θα εντοπίσουν την δεξιότερη και πιο κάτω τιμή στον πίνακα. Για τη τιμή 488 θα επιστρέψουν ΣΠΑΡΤΗ /Αυγ-11 και όχι ΒΟΛΟΣ / Φεβ-11.
Όλες οι συναρτήσεις και οι μορφοποιήσεις θα δουλέψουν είτε οι πίνακες περιέχουν αριθμούς είτε κείμενο.

Κατεβάστε το excel βιβλίο:table_functions για να δείτε τους τύπους αυτούς στην πράξη.

This entry was posted in excel, Μορφοποίηση υπό όρους, Συναρτήσεις φύλλου and tagged , , , , . Bookmark the permalink.

17 Responses to Δουλεύοντας με ένα πίνακα

  1. Ο/Η ΛΑΜΠΡΙΝΗ ΖΩΤΟΥ λέει:

    ΘΑ ΗΘΕΛΑ ΝΑ ΡΩΤΉΣΩ ΠΩΣ ΣΥΝΕΧΊΖΕΙ ΝΑ ΑΚΟΛΟΥΘΕΊ ΜΙΑ ΣΤΗΛΗ ΕΝΩ ΔΟΥΛΕΥΕΙΣ ΣΤΟ ΤΈΛΟΣ ΤΟΥ ΠΙΝΑΚΑ ,ΠΧ. ΑΝ ΔΟΥΛΕΥΕΙΣ ΕΝΑ ΠΙΝΑΚΑ ΜΙΣΘΟΔΟΣΙΑΣ ΑΝΑ ΜΗΝΑ ΠΩΣ ΘΑ ΜΠΟΡΕΊΣ ΝΑ ΒΛΕΠΕΙΣ ΤΗΝ ΣΤΗΛΗ ΤΩΝ ΟΝΟΜΑΤΩΝ ΕΝΩ ΔΟΥΛΕΥΕΙΣ ΤΟΝ ΔΕΚΕΜΒΡΙΟ?

    Λαμπρινή Ζώτου

  2. Ο/Η vioannis λέει:

    Αν ο κατάλογος των ονομάτων είναι πχ στη στήλη D, τότε επίλεξε (κάνε κλικ) στο κελί E1 και στο μενού: Προβολή > Σταθεροποίηση παραθύρων > Σταθεροποίηση τμημάτων παραθύρου . Η ίδια εργασία για να ακυρώσεις την σταθεροποίηση. (Περιγραφή για excel 2007) Για παλιότερες εκδόσεις του excel, μενού: Παράθυρο > Σταθεροποίηση τμημάτων παραθύρου .

  3. Ο/Η apostolos orfanidis λέει:

    Γιαννη καλη σου Εβδομαδα .
    Ε χω ενα προβλημα που εδω και 1 μηνα με απασχολει . Στο περιγραφω ..πινακας

    .serv / breaks……………εως….| 100 gr | 2,5 κιλα | 10 κιλα | 20 κιλα | 30 κιλα | 1000 κιλα|
    υπηρεσια εως 100 γρ…………. | 0,1 | 0,1 | 0,1 | | |
    υπηρεσ express εωσ 2,5 κιλα.| | 0,5 | | | |
    οικον αεροπορ μεταφορ εως | | 0,5 | 0,5 | 1 | 2 | 5
    οδικη μεταφορα εως | | | 1 | 2 | 5 | 10

    services = διαφορες υπηρεσιες μεταφορας

    brakes = σπασιματα ( σημαινει οτι η τιμη του βαρους επιστρέφει τον αριθμό που είναι στο πλησιέστερο σημαντικό πολλαπλάσιο που περιγραφεται στον πινακα )

    για παραδειγμα εαν εχουμε την οικονομικη αεροπ μεταφορα βαρους 20,2 το αποτελεσμα που πρεπι να λαβουμε ειναι 21 κιλα ( επειδη θα το λαβει με την συναρτηση ceiling τον αριθμο ορισμα 1 που εχω επιλεξει )

    αντιστοιχα εαν εχει επιλεχθει η οδικη μεταφορα και το βαρος ειναι 30,8 θα πρεπει να λαβω
    αποτελεσμα 35 ( επειδη το ορισμα στην συνατηση ceiling θα ειναι το 5 ) .

    η συναρτηση ceiling Επιστρέφει έναν αριθμό …, που είναι στρογγυλοποιημένος προς τα επάνω στο πλησιέστερο σημαντικό πολλαπλάσιο όρισμα ( Το αναφερω γιατί μπορει καποιος να μην γνωριζει την υπαρξη αυτης της συναρτησης )

    Εως τωρα εχω καταφερει να επιλυσω το προβλημα με 2 τροπους .

    α) με πολλα ( and και if ) …κανει δουλεια αλλα εαν θελω παραμετροποιησω κατι … πρεπει να επεμβω στην συναρτηση
    β ) με το παραδειγμα σου εναλλακτικες μορφες της συναρτησης if ( εξαιρετικη δουλεια !!! ) μονο που δεν μπορω να το χρησιμοποιησω ταυτοχρονα οταν εχω παραπανω απο μια εγγραφη …

    θα ηθελα λοιπον μια λυση πινακα ισως με την choose ωστε να μπορω να δουλευω ταυτοχρονα
    πολλες πιθανες περιπτωσεις για παραδειγμα

    βαρος αποστολης χρεωσιμο βαρος
    υπηρεσ express εωσ 2,5 κιλα 0,8 1
    οικον αεροπορικη μεταφορ 32,250 35

    κ.α
    ελπιζω να εγινα κατανοητος και να μην σε παιδεψω

    ευχαριστω πολυ για ολα

  4. Ο/Η apostolos orfanidis λέει:

    serv / breaks…εως….| 100 kgr | 2,5 kgr| 10 kgr | 20 kgr | 30 kgr | 1000 kgr
    υπηρεσια εως100 gr | 0,1 ——| 0,1 —-| 0,1 —-|———- |——- |———
    υπηρ express εωσ 2,5| ———-| 0,5 —-| ———| ———-| ——-|———
    οικον αεροπ μεταφ ΄΄΄΄ | ———| 0,5—- | 0,5 —-| 1——– | 2—- | 5——
    οδικη μεταφορα εως — |———|———-| 1——- | 2——– | 5—- | 10—–΄

    ξαναφτιαχνω τον πινακα ceiling ετσι ωστε να ειναι πιο ευδιακριτος

    ευχαριστω και παλι για οτι βοηθεια μου εχεις προσφερει .

  5. Ο/Η vioannis λέει:

    Απόστολε,
    Νομίζω πως κατάλαβα το πρόβλημα και αν είναι αυτό που κατάλαβα, έχει πολύ ενδιαφέρον. Σου δίνω μία διαφορετική προσέγγιση από τις If, όπως πολύ σωστά ζήτησες. Στην προσέγγιση αυτή, ο συντελεστής στρογγυλοποίησης (significance) της CEILING εντοπίζεται στον πίνακα με ένα συνδυασμό της LOOKUP και της VLOOKUP. Δες το στην πράξη, στο excel βιβλίο ceiling_and_lookup.xls. Η lookup ίσως σου φανεί δυσνόητη με τον τρόπο που την χρησιμοποιώ, γι αυτό στο βιβλίο θα βρεις έναν πίνακα παραδειγμάτων που ίσως βοηθήσει. Αν κάτι δεν έχει πάει καλά, επανέρχεσαι.

  6. Ο/Η apostolos orfanidis λέει:

    Γιαννη ευχαριστω πολυ..

    .διαβαζω και επανερχομαι

  7. Ο/Η Apostolos orfanidis λέει:

    Γιάννη εξαιρετικό .το τσεκαρα σήμερα . Η εμπειρια σου με τον διορθωτικο παράγοντα ευρηματική και πάλι ευχαριστω για όλα.

  8. Ο/Η apostolos orfanidis λέει:

    ΔΑΣΚΑΛΕ ΚΑΛΗΜΕΡΑ .
    ΕΛΠΙΖΩ ΝΑ ΠΑΣ ΣΥΝΤΟΜΑ ΔΙΑΚΟΠΕΣ ΚΑΙ ΝΑ ΞΕΚΟΥΡΑΣΤΕΙΣ ΑΠΟ ΟΛΕΣ ΑΥΤΕΣ ΤΙΣ ΕΡΩΤΗΣΕΙΣ ΠΟΥ ΣΟΥ ΚΑΝΟΥΜΕ ΚΑΘΗΜΕΡΙΝΑ.
    Η ΣΗΜΕΡΙΝΗ ΕΡΩΤΗΣΗ ΕΧΕΙ ΝΑ ΚΑΝΕΙ ΜΕ ΤΗΝ ΣΥΝΑΡΤΗΣΗ LOOKUP.

    Στο παραδειγμα που μου εστειλες θα ηθελα να δω εαν μπορει να γινει μια παραμετροποιηση.
    Στήλη: 6 <— Η συνάρτησης lookup, επιστρέφει τον αριθμό της στήλης του πίνακα που αντιστοιχεί το βάρος (ο πίνακας έχει 7 στήλες).
    Η lookup ειναι γραμμένη ετσι.

    =LOOKUP(B10;{0,1\2,5\10\20\30\1000}+10^-6;{2\3\4\5\6\7})
    θα ηθελα εαν μπορει να γινει το εξης :H πρωτη αγκυλη αντι να βλεπει στους αριθμους που εχουμε γραψει δηλ {0,1\2,5\10\20\30\1000} να βλεπει στο περιεχομενο των αντιστοιχων κελιων C2,D2,E2….
    Ο λογος που θα το ηθελα ειναι για να μην εχει ο χρηστης προσβαση στην συναρτηση αλλα για να μπορει να αλλαζει τα δεδομενα της αλλαζοντας τις τιμες των κελιων , ανα πασα στιγμη.

    ΕΥΧΑΡΙΣΤΩ ΠΟΛΥ ΚΑΙ ΠΑΛΙ ΓΙΑ ΟΛΑ

  9. Ο/Η vioannis λέει:

    Απόστολε, δες εδώ στο ceiling_and_lookup_new.xls, δύο-τρεις παραλλαγές της αλλαγής που ζήτησες. Πες μου αν σε κάλυψα. Ναι, θα φύγω για λίγες ημέρες, θα πάω να ψαρέψω αληθινά ψάρια και όχι συναρτήσεις σε εξελόφυλλα…

  10. Ο/Η apostolos λέει:

    Αγαπητέ δάσκαλε όπως βλέπεις επανέρχομαι με μια νέα ερώτηση σχετικά με το πολύ όμορφο παράδειγμα που αναφέρεις παραπάνω (Αναζήτηση διασταύρωσης. Συναρτήσεις και υπερσύνδεση).
    θα ζητήσω μια αλλαγή και θα ήθελα να με βοηθήσεις .
    στην κoλoνα β τοποθετώ πωλητές πχ στο κελί β10 νικος – στο κελί β11 τασος κ.ο.κ
    στην κολόνα cτοποθετώ μάρκες αυτοκινήτων πχ στο κελί c11 audi c12 opel κ.ο.κ
    στο κελί α3 δημιουργώ επικύρωση πωλητών
    στο κελί α4 δημιουργώ επικύρωση με τις μάρκες των αυτοκινήτων.

    υπάρχει τελικά η δυνατότητα ? να λάβω διασταύρωση έχοντας 4 παραμετρικά επικυρωμένα κελιά αναζητήσεών ….( πωλητής – μάρκα αυτοκίνητου -ημερομηνία και περιοχή ?

    δοκίμασα κάποιες τεχνικές με choose & vlookup με αλλά δεν ήταν κάτι ολοκληρωτικό.

    ευχαριστώ πολύ για όλα.

    Απόστολος

  11. Ο/Η vioannis λέει:

    Απόστολε, δεν σε ξέχασα, απλά προσπαθώ να σε καταλάβω. Έχεις λες 4 κελιά με επικύρωση (πωλητής – μάρκα αυτοκίνητου -ημερομηνία και περιοχή) τα δεδομένα των πωλητών στη στήλη Β, μάρκες στη C. Ημερομηνίες και περιοχή που; Θες να κάνεις έρευνα λαμβάνοντας υπ όψη και τις 4 τιμές των κελιών της επικύρωσης. Τι θα σου επιστρέφει η έρευνα;

  12. Ο/Η apostolos orfanidis λέει:

    ΗΜ/ΝΙΑ ΠΩΛΗΤΗΣ ΒΟΛΟΣ ΡΟΔΟΣ ΠΑΤΡΑ ΣΠΑΡΤΗ
    Ιαν-11 ΜΑΡΙΟΣ 340 200 468 278
    Ιαν-11 ΠΕΤΡΟΣ 488 361 283 430
    Ιαν-11 ΝΤΙΝΟΣ 214 205 342 385
    Ιαν-11 ΚΩΣΤΑΣ 369 261 343 464
    Ιαν-11 ΛΕΥΤΕΡΗΣ 486 276 132 154
    Ιουν-11 ΜΑΡΙΟΣ 476 356 486 169
    Ιουν-11 ΠΕΤΡΟΣ 219 270 196 423
    Ιουν-11 ΝΤΙΝΟΣ 317 248 307 488
    Ιουν-11 ΚΩΣΤΑΣ 125 182 134 185
    Ιουν-11 ΛΕΥΤΕΡΗΣ 358 369 225 440

    ΑΓΑΠΗΤΕ ΓΙΑΝΝΗ ΕΦΤΙΑΞΑ ΕΝΑ ΠΙΝΑΚΑ ΓΙΑ ΝΑ ΓΙΝΩ ΠΙΟ ΑΝΑΛΥΤΙΚΟΣ , καμιά φορά η ταχύτητα σκέψης μου δεν περιγράφουν αυτά που θέλω πραγματικά και χωρίς να το θέλω σε παιδεύω .

    Στον παραπάνω πινάκα Αναζήτηση διασταύρωσης, θα δεις ότι στην ίδια ημερομηνία π.χ.
    ιουν-11 διάφοροι πωλητές ( ΜΑΡΙΟΣ ΝΤΙΝΟΣ κλπ ) έχουν εκτελέσει διάφορα ασφαλιστικά συμβόλαια σε διαφορετικές περιοχές.
    θα ήθελα λοιπόν να επιλέγω α) ημερομηνία β ) πωλητής γ ) νομός και να έχω μορφοποιημενο αποτέλεσμα

    Για παράδειγμα εάν διαλεξω α) Ιουν-11 β) ΚΩΣΤΑΣ γ ) πατρα … να έχω αποτέλεσμα 134
    και να υπάρχουν οι γραμμοσκιασεις ώστε να είναι εύκολο να παρατηρηθεί το αποτέλεσμα οπτικά
    όπως στο παράδειγμα σου.

    και πάλι ευχαριστώ για όλη την βοήθεια που μου προσφέρεις .

  13. Ο/Η vioannis λέει:

    Απόστολε
    Το ωραίο θέμα σου μπορεί να αντιμετωπιστεί με διπλό vlookup. Δες αναλυτικά τα βήματα πριν φτάσουμε στο τελικό τύπο στο βιβλίο Double_vlookup_in_table.xls. Δεν είναι ο μοναδικός τρόπος να αντιμετωπιστεί, αλλά σε κάθε περίπτωση δεν είναι απλό θέμα. Προτίμησα το διπλό vlookup διότι μπορεί να επεκταθεί και να γίνει τριπλό τετραπλό κλπ. Οι τελικοί τύποι είναι λίγο τρομακτικοί, αλλά είναι απολύτως λειτουργικοί. Το ίδιο το παράδειγμα το έστησα και με δυναμικά καθορισμένα ονόματα γατί προφανώς η βάση δεδομένων θα επεκτείνεται προς τα κάτω συνεχώς και για να έχεις τελικούς τύπους πιο συμμαζεμένους.

  14. Ο/Η apostolos λέει:

    Αγαπητέ Γιάννη σε ευχαριστώ για την τόσο τεκμηριωμένη-λύση απάντηση σου .
    Προχωρώ βηματικά μια προς μια τις υποδείξεις σου.
    Στην ουσία των πραγμάτων η κάθε σου υπόδειξη- λύση είναι κεφαλαίο εντατικής διερεύνησης.
    Είναι αυτό που λέει η γενια μας ….. » που το πάει ο ποιητής » ….χι χι χι
    Μιά πρώτη ερώτηση είναι η εξης :
    στο παράδειγμα μας αναφέρεις

    Παρόμοια, ο παρακάτω τύπος δίνει τον αριθμό στήλης της επιλεγμένης πόλης στο κελί Κ3:
    4 {=HLOOKUP(K3;CHOOSE({1\2};C1:F1;COLUMN(C1:F1));2;FALSE)}
    γιατί χρησιμοποιεις C1:F1 και οχι Α1:F1 ???
    αυτό το ρωτώ γιατι το αποτέλεσμα 4 αντιπροσωπεύει τον πίνακα Α1:F1 που ειναι στην ουσια ο
    αριθμός στήλης.

    ευχαριστώ πολύ και επανέρχομαι ….
    καλή συνέχεια

  15. Ο/Η vioannis λέει:

    Παρέλειψα τα κελιά Α1 και Β1, διότι εκεί δεν θα βρω τιμή Κ3 δηλαδή πόλη, έβαλα και κάνα- δύο κενά κελιά δεξιά μήπως στο μέλλον προστεθούν πόλεις. Ξεκίνα από Α1, δεν υπάρχει διαφορά.

  16. Ο/Η apostolos λέει:

    Αγαπητέ Γιαννη σε ευχαριστώ πάρα πολύ γιε την ευγενική διάθεση να με βοηθάς , να ξέρεις ότι όταν πραγματικά φτάνω σε αδυναμία προχωρώ σε ερώτηση . Γνωρίζω βέβαια μέσα από το blog σου τις ευχαριστίες που λαμβάνεις καθημερινά από ανθρώπους που λύνουν τυχόν απορίες τους.
    Θα πρέπει λοιπόν και εγώ να σε ευχαριστήσω γιατί την λύση στα προβλήματα που σου θέτω πυκνά συχνά . Είναι προφανές ότι είναι πολύ λίγο αυτό κυρίως γιατί δεν είναι η λύση του προβλήματος αυτού καθ αυτού , αλλά όλη σου η στάση σου και η συμπεριφορά σου ως άνθρωπος – δάσκαλος .
    Σαν μαθητής σου ετών 49 έχω ένα βιβλίο με αμέτρητα ζωντανά παραδείγματα ( το blog σου ) ,καθημερινά το παρακολουθώ και χαίρομαι που σε πολλά από τα ερωτήματα ξέρω πια που υπάρχει η λύση .
    Δεν έχω κάτι άλλο να σου πω άπλα … ένα μεγάλο μπράβο , Συνέχισε

    Αποστολος

  17. Ο/Η vioannis λέει:

    Αγαπητέ Απόστολε, χίλια ευχαριστώ για το τόσο θερμό και πολύ ενθαρρυντικό μήνυμά σου. Ο χαρακτηρισμός “δάσκαλος” με βαραίνει και με αγχώνει λίγο. Ας πούμε απλά ότι μοιράζομαι με τους διαδικτυακούς φίλους που απέκτησα μέσω του ιστολογίου(και που ελπίζω ότι θα συνεχίσω να αποκτώ και στο μέλλον), την εμπειρία μου με τα φύλλα λογισμού, μια και είμαι συστηματικός χρήστης από το 1985 (από το Lotus 123-έκδοση 1.01). Άλλωστε, μη νομίζεις ότι η σχέση με τους φίλους είναι μονομερής, μερικά από τα ερωτήματά τους με έχουν αιφνιδιάσει και με έχουν αναγκάσει να ανοίξω βιβλία, να ψάξω στο δίκτυο, να ανατρέξω σε παλιά αρχεία και σημειώσεις, να ξαναθυμηθώ παλιές και να μάθω νέες τεχνικές. Όπως έχω ξαναπεί, σαν ερασιτέχνης που είμαι, δεν είμαι παντογνώστης, απλά βάζω τα δυνατά μου. Και βάζω τα δυνατά μου…διότι μου αρέσει!
    Και πάλι ευχαριστώ Απόστολε!

Τα σχόλια είναι απενεργοποιημένα.