Και άλλες συναρτήσεις ημερομηνίας και χρόνου

Τα στατιστικά στοιχεία της wordpress.com για το ιστολόγιο, με πληροφορούν ότι πολλοί από τους επισκέπτες του, ενδιαφέρονται για συναρτήσεις ημερομηνίας και χρόνου. Αναρτήσεις όπως  «ISO 8601 στο Excel«, «Μία ημερομηνία σε ποια εβδομάδα του έτους ανήκει;» «Επίσημες Αργίες για κάθε έτος» έχουν σημαντική επισκεψιμότητα. Αφού λοιπόν υπάρχει ενδιαφέρον, επανέρχομαι με μερικές ακόμα χρήσιμες συναρτήσεις φύλλου που αφορούν ημερομηνίες:
Α) Στο κελί Α1 είναι μία ημερομηνία. Η συνάρτηση: =A1+MOD(-WEEKDAY(A1);7)+1 θα επιστέψει την επόμενη Κυριακή της ημερομηνίας στο κελί Α1. Την επόμενη Δεύτερα δίνει ο τύπος:  =A1+MOD(1-WEEKDAY(A1);7)+1. Για όλες τις ημέρες της εβδομάδος οι τύποι είναι:
Για την επόμενη Κυριακή:
=A1+MOD(0-WEEKDAY(A1);7)+1
Για την επόμενη Δευτέρα:
=A1+MOD(1-WEEKDAY(A1);7)+1
Για την επόμενη Τρίτη:
=A1+MOD(2-WEEKDAY(A1);7)+1
Για την επόμενη Τετάρτη:
=A1+MOD(3-WEEKDAY(A1);7)+1
Για την επόμενη Πέμπτη:
=A1+MOD(4-WEEKDAY(A1);7)+1
Για την επόμενη Παρασκευή:
=A1+MOD(5-WEEKDAY(A1);7)+1
Για το επόμενο Σάββατο:
=A1+MOD(6-WEEKDAY(A1);7)+1
Β) Οι προηγούμενοι τύποι επιστρέφουν την ημερομηνία που είναι από 1 έως 7 ημέρες πιο εμπρός από την  ημερομηνία του κελιού Α1. Οι παρακάτω τύποι επιστρέφουν την ημερομηνία που είναι από 0 έως 6 ημέρες πιο εμπρός από την  ημερομηνία του κελιού Α1, δηλαδή επιστρέφουν ότι και οι προηγούμενοι,  αλλά ειδικά για την ημέρα του κελιού Α1, επιστρέφουν την ίδια την ημερομηνία του Α1. Αν δηλαδή η ημέρα στο κελί Α1 είναι Τρίτη, οι παρακάτω συναρτήσεις, θα επιστρέψουν την επόμενη Δευτέρα, Τετάρτη, Πέμπτη κλπ αλλά ειδικά για την Τρίτη θα επιστρέψουν την ίδια Τρίτη του κελιού Α1
Για την επόμενη Κυριακή:
=A1+MOD(1-WEEKDAY(A1);7)
Για την επόμενη Δευτέρα:
=A1+MOD(2-WEEKDAY(A1);7)
Για την επόμενη Τρίτη:
=A1+MOD(3-WEEKDAY(A1);7)
Για την επόμενη Τετάρτη:
=A1+MOD(4-WEEKDAY(A1);7)
Για την επόμενη Πέμπτη:
=A1+MOD(5-WEEKDAY(A1);7)
Για την επόμενη Παρασκευή:
=A1+MOD(6-WEEKDAY(A1);7)
Για το επόμενο Σάββατο:
=A1+MOD(7-WEEKDAY(A1);7)
Γ) Αν θέλετε να μεταβείτε σε προηγούμενες ημέρες (0 έως 6 ημέρες πίσω) :
Για την προηγούμενη Κυριακή:
=A1-MOD(WEEKDAY(A1)-1;7)
Για την προηγούμενη Δευτέρα:
=A1-MOD(WEEKDAY(A1)-2;7)
Για την προηγούμενη Τρίτη:
=A1-MOD(WEEKDAY(A1)-3;7)
Για την προηγούμενη Τετάρτη:
=A1-MOD(WEEKDAY(A1)-4;7)
Για την προηγούμενη Πέμπτη:
=A1-MOD(WEEKDAY(A1)-5;7)
Για την προηγούμενη Παρασκευή:
=A1-MOD(WEEKDAY(A1)-6;7)
Για το προηγούμενο Σάββατο:
=A1-MOD(WEEKDAY(A1)-7;7)
ή
=A1-MOD(WEEKDAY(A1);7)
Δ)  Αν θέλετε να μεταβείτε σε προηγούμενες ημέρες (1 έως 7 ημέρες πίσω), εφαρμόστε τους προηγούμενους τύπους για την προηγούμενη ημέρα της Α1. Δηλαδή στη θέση του ορίσματος Α1 βάλτε Α1-1 και οι τύποι θα γίνουν:
Για την προηγούμενη Κυριακή:
=A1-1-MOD(WEEKDAY(A1-1)-1;7)
Για την προηγούμενη Δευτέρα:
=A1-1-MOD(WEEKDAY(A1-1)-2;7)
Για την προηγούμενη Τρίτη:
=A1-1-MOD(WEEKDAY(A1-1)-3;7)
Για την προηγούμενη Τετάρτη:
=A1-1-MOD(WEEKDAY(A1-1)-4;7)
Για την προηγούμενη Πέμπτη:
=A1-1-MOD(WEEKDAY(A1-1)-5;7)
Για την προηγούμενη Παρασκευή:
=A1-1-MOD(WEEKDAY(A1-1)-6;7
Για το προηγούμενο Σάββατο:
=A1-1-MOD(WEEKDAY(A1-1)-7;7)
ή
=A1-1-MOD(WEEKDAY(A1-1);7)
Ε) Σε όλους τους παραπάνω τύπους, αντικαταστήστε το όρισμα Α1 με την συνάρτηση TODAY(), για να μεταβείτε στις αντίστοιχες ημέρες, από την τρέχουσα (σημερινή) ημερομηνία. Παράδειγμα, για την επόμενη Κυριακή, μετά από σήμερα:
=TODAY()+MOD(-WEEKDAY(TODAY());7)+1
ΣΤ) Αν στο κελί Α1 είναι η πρώτη ημέρα ενός μήνα, οι τύποι της ομάδας (Β) θα δώσουν την πρώτη Κυριακή, την πρώτη Δευτέρα, την πρώτη Τρίτη κλπ του μήνα. Πιο καλά, αντικαταστήστε το όρισμα Α1 με την συνάρτηση DATE(year, month, day)  όπου year  και month είναι αντίστοιχα το έτος και ο μήνας και day=1. Παράδειγμα για τον Οκτώβριο 2011 στη θέση του Α1 βάλτε: DATE(2011,10,1)  και τότε,
η πρώτη Κυριακή  είναι:
=DATE(2011;10;1)+MOD(1-WEEKDAY(DATE(2011;10;1));7)
Η πρώτη Δευτέρα είναι:
=DATE(2011;10;1)+MOD(2-WEEKDAY(DATE(2011;10;1));7)
Η πρώτη Τρίτη είναι:
=DATE(2011;10;1)+MOD(3-WEEKDAY(DATE(2011;10;1));7)
........

  Μπορείτε να συντάξετε τις παραπάνω συναρτήσεις και ως εξής:
="1/10/2011"+MOD(1-WEEKDAY("1/10/2011");7)
="1/10/2011"+MOD(2-WEEKDAY("1/10/2011");7)
="1/10/2011"+MOD(3-WEEKDAY("1/10/2011");7)
......
Αν στο κελί Α1 είναι μια οποιαδήποτε ημερομηνία και  θέλετε την πρώτη Κυριακή  του μήνα της ημερομηνίας αυτής, χρησιμοποιήστε το τύπο:
=DATE(YEAR(A1);MONTH(A1);1)+MOD(1-WEEKDAY(DATE(YEAR(A1);MONTH(A1);1));7)
Ο τύπος αυτός προέκυψε από τον πρώτο τύπο της (Β) παραγράφου, με αντικατάσταση του Α1 με:
DATE(YEAR(A1);MONTH(A1);1). Παρόμοια και οι τύποι για τις άλλες ημέρες.
Ζ) Μπορείτε τώρα να απαντήσετε στο ερώτημα: Πόσες Κυριακές έχει ένας μήνας;
Την απάντηση δίνει ο τύπος:
(Πρώτη Κυριακή επόμενου μήνα –  Πρώτη Κυριακή μήνα )/7
Για το μήνα Οκτώβριο 2011:
Πρώτη Κυριακή επόμενου μήνα =DATE(2011;11;1)+MOD(1-WEEKDAY(DATE(2011;11;1));7)
Πρώτη Κυριακή μήνα=DATE(2011;10;1)+MOD(1-WEEKDAY(DATE(2011;10;1));7), άρα:
Πλήθος Κυριακών:
=( DATE(2011;11;1)+MOD(1-WEEKDAY(DATE(2011;11;1));7)- DATE(2011;10;1)-MOD(1-WEEKDAY(DATE(2011;10;1));7))/7
Παρόμοια, πλήθος από Δευτέρες:
=( DATE(2011;11;1)+MOD(2-WEEKDAY(DATE(2011;11;1));7)- DATE(2011;10;1)-MOD(2-WEEKDAY(DATE(2011;10;1));7))/7 
...........κλπ
Αν στο κελί Α1 είναι μια οποιαδήποτε ημερομηνία και  θέλετε τοπλήθος κάποιων ημερών  του μήνα της ημερομηνίας αυτής, χρησιμοποιήστε τους τύπους:
Πλήθος Κυριακών:
=(DATE(YEAR(A1);MONTH(A1)+1;1)+MOD(1-WEEKDAY(DATE(YEAR(A1);MONTH(A1)+1;1));7) -DATE(YEAR(A1);MONTH(A1);1)-MOD(1-WEEKDAY(DATE(YEAR(A1);MONTH(A1);1));7))/7
Πλήθος από Δευτέρες:
=(DATE(YEAR(A1);MONTH(A1)+1;1)+MOD(2-WEEKDAY(DATE(YEAR(A1);MONTH(A1)+1;1));7) -DATE(YEAR(A1);MONTH(A1);1)-MOD(2-WEEKDAY(DATE(YEAR(A1);MONTH(A1);1));7))/7
Πλήθος από Τρίτες:
=(DATE(YEAR(A1);MONTH(A1)+1;1)+MOD(3-WEEKDAY(DATE(YEAR(A1);MONTH(A1)+1;1));7) -DATE(YEAR(A1);MONTH(A1);1)-MOD(3-WEEKDAY(DATE(YEAR(A1);MONTH(A1);1));7))/7
..............κλπ
Η) Κάνοντας χρήση την συναρτήσεων της παραγράφου (Δ), που δίνουν την προηγουμένη επιλεγμένη ημέρα μιας ημερομηνίας, μπορείτε να βρείτε την τελευταία επιλεγμένη ημέρα ενός μήνα. Εφαρμόστε τις συναρτήσεις για την πρωτομηνιά του επόμενου μήνα.
Για να βρείτε την τελευταία Κυριακή του Οκτωβρίου 2011 στον πρώτο τύπο της παραγράφου Δ:
=A1-1-MOD(WEEKDAY(A1-1)-1;7) αντικαταστήστε το όρισμα Α1 με DATE(2011;11;1) και ο τύπος θα γίνει:
= DATE(2011;11;1) -1-MOD(WEEKDAY(DATE(2011;11;1) -1)-1;7)
Αν στο κελί Α1 είναι μια οποιαδήποτε ημερομηνία και  θέλετε την τελευταία Κυριακή  του μήνα της ημερομηνίας αυτής, χρησιμοποιήστε το τύπο:
= DATE(YEAR(A1);MONTH(A1)+1;1) -1-MOD(WEEKDAY(DATE(YEAR(A1);MONTH(A1)+1;1) -1)-1;7)
Για την τελευταία Δευτέρα:
= DATE(YEAR(A1);MONTH(A1)+1;1) -1-MOD(WEEKDAY(DATE(YEAR(A1);MONTH(A1)+1;1) -1)-2;7)
Για την τελευταία Τρίτη:
= DATE(YEAR(A1);MONTH(A1)+1;1) -1-MOD(WEEKDAY(DATE(YEAR(A1);MONTH(A1)+1;1) -1)-3;7)
Για την τελευταία Τετάρτη:
= DATE(YEAR(A1);MONTH(A1)+1;1) -1-MOD(WEEKDAY(DATE(YEAR(A1);MONTH(A1)+1;1) -1)-4;7)
Για την τελευταία Πέμτη:
= DATE(YEAR(A1);MONTH(A1)+1;1) -1-MOD(WEEKDAY(DATE(YEAR(A1);MONTH(A1)+1;1) -1)-5;7)
Για την τελευταία Παρασκευή:
= DATE(YEAR(A1);MONTH(A1)+1;1) -1-MOD(WEEKDAY(DATE(YEAR(A1);MONTH(A1)+1;1) -1)-6;7)
Για το τελευταίο Σάββατο:
= DATE(YEAR(A1);MONTH(A1)+1;1) -1-MOD(WEEKDAY(DATE(YEAR(A1);MONTH(A1)+1;1) -1)-7;7)
Θ)  Στο κελί Α1 είναι μία ημερομηνία. Η συνάρτηση: =A1+1-WEEKDAY(A1) θα επιστρέψει την Κυριακή της εβδομάδας της ημερομηνίας του κελιού Α1. Τη Δεύτερα της ίδιας εβδομάδας δίνει ο τύπος:  =A1+2-WEEKDAY(A1)1. Για όλες τις ημέρες της εβδομάδος οι τύποι είναι:
Η Κυριακή της ίδιας εβδομάδας:
=A1+1-WEEKDAY(A1)
Η Δευτέρα της ίδιας εβδομάδας:
=A1+2-WEEKDAY(A1)
Η Τρίτη της ίδιας εβδομάδας:
=A1+3-WEEKDAY(A1)
Η Τετάρτη της ίδιας εβδομάδας:
=A1+4-WEEKDAY(A1)
Η Πέμπτη της ίδιας εβδομάδας:
=A1+5-WEEKDAY(A1)
Η Παρασκευή της ίδιας εβδομάδας:
=A1+6-WEEKDAY(A1)
Το Σάββατο της ίδιας εβδομάδας:
=A1+7-WEEKDAY(A1)
Στους παραπάνω τύπους η εβδομάδα θεωρήθηκε ότι ξεκινά Κυριακή. Έτσι αν στο κελί Α1 είναι πχ μία Τετάρτη, η συνάρτηση της Κυριακής θα επιστρέψει την Κυριακή που προηγήθηκε και αν στο κελί είναι Κυριακή, οι παραπάνω συναρτήσεις θα επιστέψουν την εβδομάδα που ακολουθεί της Κυριακής αυτής. Αν όμως θεωρηθεί ότι η εβδομάδα ξεκινά Δευτέρα, τότε χρειάζονται άλλοι τύποι, διότι αν στο κελί Α1είναι Τετάρτη, η συνάρτηση της Κυριακής πρέπει να επιστρέψει την επόμενη Κυριακή, και αν στο κελί είναι Κυριακή, οι συναρτήσεις πρέπει να επιστρέψουν την εβδομάδα που προηγήθηκε.
Αν λοιπόν, θεωρείτε πρώτη ημέρα της εβδομάδας τη Δευτέρα οι τύποι είναι:
Η Δευτέρα της ίδιας εβδομάδας:
=A1+1-WEEKDAY(A1;2)
Η Τρίτη της ίδιας εβδομάδας:
=A1+2-WEEKDAY(A1;2)
Η Τετάρτη της ίδιας εβδομάδας:
=A1+3-WEEKDAY(A1;2)
Η Πέμπτη της ίδιας εβδομάδας:
=A1+4-WEEKDAY(A1;2)
Η Παρασκευή της ίδιας εβδομάδας:
=A1+5-WEEKDAY(A1;2)
Το Σάββατο της ίδιας εβδομάδας:
=A1+6-WEEKDAY(A1;2)
Η Κυριακή της ίδιας εβδομάδας:
=A1+7-WEEKDAY(A1;2)

Ή ισοδύναμα:
Η Δευτέρα της ίδιας εβδομάδας:
=A1+0-WEEKDAY(A1;3)
Η Τρίτη της ίδιας εβδομάδας:
=A1+1-WEEKDAY(A1;3)
Η Τετάρτη της ίδιας εβδομάδας:
=A1+2-WEEKDAY(A1;3)
Η Πέμπτη της ίδιας εβδομάδας:
=A1+3-WEEKDAY(A1;3)
Η Παρασκευή της ίδιας εβδομάδας:
=A1+4-WEEKDAY(A1;3)
Το Σάββατο της ίδιας εβδομάδας:
=A1+5-WEEKDAY(A1;3)
Η Κυριακή της ίδιας εβδομάδας;
=A1+6-WEEKDAY(A1;3)
Σημείωση: Για κάποιες από τις παραπάνω περιπτώσεις μπορούν να γραφούν πιο σύντομες συναρτήσεις. Παράδειγμα για το προηγούμενο Σάββατο  =A1-WEEKDAY(A1), για την επόμενη Κυριακή =A1+8-WEEKDAY(A1) και άλλες πολλές. Εδώ έγινε προσπάθεια όλη η παρουσίαση να γίνει με ενιαία και συνεχόμενη λογική.

Το παραπάνω σημείωμα μπορείτε να δείτε και στο PDF αρχείο:ExcelDays
Τις συναρτήσεις μπορείτε να δείτε στο excel βιβλίο: date_time_functions

This entry was posted in excel, Συναρτήσεις φύλλου and tagged , , . Bookmark the permalink.

6 απαντήσεις στο Και άλλες συναρτήσεις ημερομηνίας και χρόνου

  1. Ο/Η Γιώργος λέει:

    έψαξα στις συναρτήσεις ημερομηνιάς – χρόνου που κατά καιρούς έχεις δώσει, δεν βρήκα και φαντάζομαι θα είναι απλό να δώσεις λύση στο εξής: Διαφορά μεταξύ δύο ημερομηνιών σε έτη, μήνες ή ημέρες λαβαίνοντας υπόψη ότι αυτό μπορεί να χρησιμοποιηθεί (για παράδειγμα) για τον υπολογισμό της προϋπηρεσίας κάποιου κλπ.

  2. Ο/Η vioannis λέει:

    Γιώργο, στις πρώτες εκδόσεις του excel υπήρχε η συνάρτηση DATEDIF. Η συνάρτηση αυτή προφανώς για λόγους συμβατότητας εξακολουθεί να υπάρχει στο excel , απλώς δεν γράφει τίποτα η βοήθεια για αυτή και δεν εμφανίζεται στον κατάλογο των συναρτήσεων. Αν θυμάμαι καλά τελευταία φορά που εμφανιζόταν επίσημα ήταν στην έκδοση 2000. Είναι παρούσα όμως και στις πρόσφατες εκδόσεις και δουλεύει μία χαρά. Δεν ξέρω γιατί έγινε ο «υποβιβασμός » αυτός της συνάρτησης στην κατηγορία την «κρυφών» ή «ντροπαλών» ☻
    Η DATEDIF υπολογίζει τον αριθμό ημερών, μηνών ή ετών ανάμεσα σε δύο ημερομηνίες. Επιστρέφει πάντα ακέραιο αριθμό. Η σύνταξη της συνάρτησης είναι:

    =DATEDIF(αρχική ημερομηνία ; τελική ημερομηνία ; μονάδα)  
    

    Τα ορίσματα αρχική και τελική ημερομηνία είναι διευθύνσεις κελιών που περιέχουν ημερομηνίες, ή συναρτήσεις που επιστρέφουν ημερομηνίες όπως TODAY, DATEVALUE, DATE κλπ ή ημερομηνίες γραμμένες σαν κείμενο μέσα σε εισαγωγικά: «εεεε/μ/η»
    Το όρισμα μονάδα παίρνει μία από τις παρακάτω τιμές, και τότε η συνάρτηση επιστρέφει αντίστοιχα:
    «y» : Τη διαφορά των ημερομηνιών σε ακέραια έτη (οι τυχόν επιπλέον μήνες και τυχόν επιπλέον ημέρες αγνοούνται)
    Παράδειγμα αν στο κελί Α1 υπάρχει : 1/1/2010 και στο κελί Β1: 25/3/2014 τότε η

     =DATEDIF(A1;B1;"y") επιστρέφει  4
    

    «m» : Τη διαφορά των ημερομηνιών σε ακέραιους μήνες (οι τυχόν επιπλέον ημέρες αγνοούνται)

    =DATEDIF(A1;B1;"m") = 50 
    

    «d» : Τη διαφορά των ημερομηνιών σε ημέρες.

    =DATEDIF(A1;B1;"d") = 1544
    

    Στην περίπτωση αυτή η συνάρτηση επιστρέφει ότι και η απλή διαφορά =Β1-Α1

    «md» : Αγνοεί ακέραια έτη και ακέραιους μήνες και επιστρέφει τη διαφορά των τυχόν επί πλέον ημερών

    =DATEDIF(A1;B1;"md") = 24 
    

    «ym» : Αγνοεί ακέραια έτη και επιστρέφει τη διαφορά των τυχόν επί πλέον μηνών (οι τυχόν επιπλέον ημέρες αγνοούνται)

    =DATEDIF(A1;B1;"ym") = 2 
    

    «yd» : Αγνοεί ακέραια έτη και επιστρέφει τη διαφορά των τυχόν επί πλέον ημερών

    =DATEDIF(A1;B1;"yd") = 83 
    

    Στη τελευταία δηλαδή περίπτωση επιστρέφει το πλήθος των ημερών από 1/1/2014 έως 25/3/2014.

    Σε όλες τις παραπάνω συντάξεις της συνάρτησης, επιστρέφει αριθμούς ενώ στην επόμενη σύνταξη:

    =DATEDIF(A1;B1;"y")&"έτη "& DATEDIF(A1;B1;"ym")&"μήνες "&DATEDIF(A1;B1;"md")&"ημέρες"
    

    θα επιστρέψει το κείμενο: 4έτη 2μήνες 24ημέρες

    Μπορείς να βάλεις στο κελί Α1 την ημερομηνία γέννησης σου και η συνάρτηση:

    =DATEDIF(A1;TODAY();"y")&"έτη "& DATEDIF(A1;TODAY();"ym")&"μήνες "&DATEDIF(A1;TODAY();"md")&"ημέρες"
    

    θα σου θυμίζει κάθε μέρα την ηλικία σου. Εφιαλτικό έτσι;

    Ο τύπος:

    =DATEDIF(A1;B1;"y")+DATEDIF(A1;B1;"yd")/365
    

    ή πιο καλά, για να καλυφτεί και η περίπτωση των δίσεκτων ετών, ο τύπος:

    =DATEDIF(A1;B1;"y")+DATEDIF(A1;B1;"yd")/(DATE(YEAR(B1)+1;1;1)-DATE(YEAR(B1);1;1))
    

    θα επιστρέψει 4,22739726 δηλαδή την διαφορά των ημερομηνιών σε έτη και δεκαδικό κλάσμα του έτους σε χρόνο 365 ή 366 ημερών. Θεωρώ τον υπολογισμό αυτόν πιο ορθολογικό από αυτόν που επιστρέφει (4,230137) η συνάρτηση =YEARFRAC(A1;B1;3)

  3. Ο/Η Γιώργος λέει:

    Ευχαριστώ πολύ. Ότι και να πω είναι λίγο. Μόνο που αφού δουλέψω λίγο με τη συνάρτηση, μάλλον θα επανέλθω με νέα ερωτήματα.

  4. Ο/Η Γιώργος λέει:

    Έτσι λοιπόν επανερχόμενος σε θέματα χρόνου-ημερομηνίας:
    Με ποιο τρόπο θα μπορούσα να πάρω μια ημερομηνία από ένα κελί, με μορφοποίηση που έχω ήδη επιλέξει (πχ. ηη, μμ ή εεεε κλπ) και να την εισάγω ως κείμενο σε μια άλλη συνάρτηση (πχ concatenate): Πολύ χρήσιμο για την δημιουργία μοναδικών κωδικών σε μεγάλα πλήθη εγγραφών, με πληροφορία χρόνου σε συνδυασμό με άλλη ιδιότητα. Ξανά ευχαριστώ.

  5. Ο/Η vioannis λέει:

    Έτσι:

    =CONCATENATE(TEXT(A1;"ηηηη,ηη-μμ-εεεε"); . . . . . . . .)
    

    όπου το δεύτερο όρισμα της TEXT είναι η ίδια η μορφοποίηση που χρησιμοποίησες στο κελί Α1 της ημερομηνίας.

  6. Ο/Η Γιώργος λέει:

    Ευχαριστώ πάρα πολύ.

Σχολιάστε

Εισάγετε τα παρακάτω στοιχεία ή επιλέξτε ένα εικονίδιο για να συνδεθείτε:

WordPress.com Logo

Σχολιάζετε χρησιμοποιώντας τον λογαριασμό WordPress.com. Log Out / Αλλαγή )

Twitter picture

Σχολιάζετε χρησιμοποιώντας τον λογαριασμό Twitter. Log Out / Αλλαγή )

Facebook photo

Σχολιάζετε χρησιμοποιώντας τον λογαριασμό Facebook. Log Out / Αλλαγή )

Google+ photo

Σχολιάζετε χρησιμοποιώντας τον λογαριασμό Google+. Log Out / Αλλαγή )

Σύνδεση με %s